//******************************************************************************
// YAYA　ゴースト
// 起動/終了トーク辞書
//******************************************************************************

//******************************************************************************
//初回起動 OnFirstBoot
//******************************************************************************

OnFirstBoot
{
	//---- 変数の初期化
	username         = "ユーザー"
	teachusername    = 0	// ユーザー名覚え用
	aitalkinterval = 180
	前回のトーク頻度 = 180
	
	"\0\s[0]どうも、\w5染田碧―そめだ　へき―　っす。\w9\w5\nやっと高校生活が終わったと思っていたら、\w5いつの間にか大人になっちゃったっすね。\w9\w5\n\s[7]あ、\w5今、\w5「脱力系のやつ」\w9って思ったっすか！？\w9\w5\n\s[0]人は自分をやる気がないとか、\w5居眠りばっかりするとか、\w5そんな風に言うっすけど、\w5これでもいつも本気っすよ。\w9\w5\n\s[2]口調はこれはまあ、\w5ご愛嬌というか…。\w9わざとじゃないっすよ。\e"
}


//******************************************************************************
//通常の起動 OnBoot
//******************************************************************************

OnBoot
{
	//---- まず双方のサーフィスを表示
	if 前回のトーク頻度 == 0
	{
		前回のトーク頻度 = 180
	}
	aitalkinterval = 前回のトーク頻度
	"\0\s[0]\1\s[10]"
	--
	//---- 起動時間を確認してあいさつを変化
	_timeslot = GetTimeSlot
	
	case _timeslot{
	when "朝"
	{
		"\0\s[0]おはよう、\w5ございますっす。\w9\w5\n\s[3]目玉焼きくらいは、\w5焼けるっすけど、\w5料理上手というほどの料理は…。\e"
	}
	when "昼"
	{
		"\0\s[0]こんにちはっす。\w9\w5\nお弁当は、\w5いつもひとりっすけど、\w5もしよかったら一緒に、\w5なんて…。\e"
	}
	when "日中"
	{
		"\0\s[0]おかえりなさい。\w9\w5\n自分と……\w9\w5\n\s[1]いや、\w5なんでもないっす。\e"
	}
	when "夜"
	{
		"\0\s[0]こんばんはっす。\w9\w5\n自分にとっては、\w5やっと一日が始まったようなもんっすね。\w9自分、\w5「朝型」\w9ではないっすから。\e"
	}
	others
	{
		//それ以外の時間の場合
		"\0\s[0]こんばんはっす。\e"
	}
	}//caseの終わり
}

//------------------------------------------------------------------------------
//朝/昼/夜などをおおざっぱに調べる関数
//------------------------------------------------------------------------------
GetTimeSlot
{
	case hour{
	when 22,23,0,1,2,3 {'深夜'}
	when 4,5,6,7,8,9,10,11 {'朝'}
	when 12,13 {'昼'}
	when 14,15,16,17 {'日中'}
	when 18,19,20,21 {'夜'}
	}//caseの終わり
}


//******************************************************************************
//終了 OnClose
//******************************************************************************

OnClose
{
	前回のトーク頻度 = aitalkinterval
	//この部分には\eつけないでね！
	_timeslot = GetTimeSlot
	if _timeslot == "朝"
	{
		//---- 朝に終了
		"\0\s[0]いってらっしゃい、\w5ませ。\w9\w5\n自分は…\w9留守番っすね。"
	}
	elseif _timeslot == "昼" || _timeslot == "日中"
	{
		//---- 昼/日中に終了
		"\0\s[3]早く戻ってきてほしいっす。\w9\w5\nでないと、\w5自分…。"
	}
	elseif _timeslot == "夜"
	{
		"\0\s[0]じゃ、\w5自分はこれで。\w9\w5\n明日も、\w5また一緒にいてほしいっす。"
	}
	else
	{
		//---- 夜/深夜に終了
		"\0\s[0]じゃ、\w5自分はこれで。\w9\w5\n明日も、\w5また一緒にいてほしいっす。"
	}
	--
	"\w9\w9\-\e"
}


//******************************************************************************
//最小化からの復帰 OnWindowStateRestore
//******************************************************************************

OnWindowStateRestore
{
	"\0\s[0]最小化から復帰したっす。\e"
}
